c$Author: fredfox $
c$Date: 2002-05-09 14:08:41 $
c$Revision: 1.7 $
c$Source: /weru/cvs/weps/weps.src/hydro/radnet.for,v $

      real function radnet (bcrlai,bweirr,snwc,bwtdmx,bwtdmn,
     *                      bmalat,bsfalw,bsfald,idoy,bwtdpt,bwzdpt)

c     + + + purpose + + +
c     this subroutine estimates the net radiation for a given area
c     using known solar radiation, air temperature, and vapor pressure
c     according to wright's (1982) modified version of penman's (1948)
c     relationship.

c     + + + key words + + +
c     radiation, hydrology, weps

c     + + + argument declarations + + +
      integer idoy
      real bcrlai
      real bweirr
      real snwc
      real bwtdmx
      real bwtdmn
      real bmalat
      real bsfalw
      real bsfald
      real bwtdpt
      real bwzdpt

c     + + + argument definitions + + +
c     bsfald   - dry albedo
c     bsfalw   - wet albedo
c     bmalat   - latitude of the site, degrees
c     idoy   - julian day of year, 1-366
c     bcrlai   - plant leaf area index
c     bwzdpt   - daily amount of percipitation, mm
c     bweirr     - solar radiation, mj/m^2
c     snwc   - water content of snow, mm
c     bwtdpt    - dew point temperature, c
c     bwtdmx   - maximum air temperature, c
c     bwtdmn   - minimum air temperature, c

c     + + + COMMON BLOCK + + +
      include 'p1const.inc'

c     + + + local variables + + +
      real albt
      real tmink
      real tmaxk
      real rnb
      real ra
      real rso
      real a
      real a1
      real b
      real e
      real rna
      real rno
      real sci

c     + + + local definitions + + +
c     albedo - overall albedo value
c     albs   - soil albedo
     

c     + + + parameters + + +

      real albp,coeff,sbc

      parameter   (albp = 0.23, coeff= -2.9e-5, sbc = 4.903e-9)

c     albp   - plant albedo
c     coeff  - coefficient in the equation to estimate soil cover index
c     sbc    - stefan-boltzmann constant, mj/m^2/day

c     + + + data initialization + + +

c     + + + FUNCTION DECLARATIONS + + +
      real radext
      real albedo

c     + + + end specifications + + +

      tmaxk = bwtdmx + 273.15									!prereq h-17
      tmink = bwtdmn + 273.15									!prereq h-17

      ra = radext(idoy, bmalat)
      rso = 0.75*ra												!h-19

      if( rso.gt.1.0e-36 ) then
          if ((bweirr/rso).gt.(0.7)) then
            a = 1.126
            b = -0.07
          else
            a = 1.017
            b = -0.06
          end if
          a1 = 0.26 + 0.1*exp(-((0.0154*(idoy - 180))**2))			!h-18
          e = exp((16.78*bwtdpt - 117)/(bwtdpt + 237.3))
          rno = (sbc*(tmaxk**4+tmink**4)/2)*(a1 - 0.139 * sqrt(e))	!h-17(b)

          albt = albedo (bcrlai, snwc, bsfalw,bsfald)
          rna = (1-albt)*bweirr										!h-17(a)

          rnb = (a*(bweirr/rso) + b)								!h-17(c)

          radnet = rna-(rno*rnb)									!h-17
      else
          radnet = 0.0
      end if

      return
      end