c**********************************************************************
c subroutine sbdzo
c**********************************************************************
      subroutine sbdzo
     i(wadir, sargo, szrgh, sxrgs, slrr,
     o wzzo)
c
c     +++ PURPOSE +++
c
c     Calc. aerodynamic roughness parm., wzzo, with no standing biomass
c
c     ++++ ARGUMENT DECLARATIONS +++
      real*4 wadir, sargo, szrgh, sxrgs, slrr
      real*4 wzzo
c
c     +++ ARGUMENT DEFINITIONS +++
c     pid180 - parameter
c     wadir  - wind direction
c     sargo  - ridge orientation
c     szrgh  - ridge height
c     sxrgs  - ridge spacing
c     sxdks  - dike spacing
c     wzzo   - aerodynamic roughness length (mm).
c
c     +++ LOCAL VARIABLES +++
      real*4 xa, sxprg, hl, wzorg, wzorr, pid180
c
c     +++ PARAMETERS +++
      parameter(pid180 = 3.14159/180)
c
c     +++ END SPECIFICATIONS +++
c
c     calc. for ridge aerodynamic roughness
      wzorg = 0.
      if (szrgh .eq. 0) go to 30
      xa   = abs ( sin( pid180 * abs( wadir - sargo)))
      if (xa .lt. 0.25) xa = 0.25
      sxprg   = sxrgs/xa
c     not used now
c     sxprg = amin1(sxprg, sxdks)
      hl   = szrgh / sxprg
      wzorg = szrgh * 1/(-64.1+135.5*hl+(20.84/sqrt(hl)))
c
c     calculation for random aerodynamic roughness
   30 wzorr = slrr*0.3
c     estimate combined ridge and random aerodynamic roughness
c     (later- no data sets at present)
c     chose the largest of the two.
      wzzo = amax1 (wzorg, wzorr)
c
      return
      end
c +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++