real function radnet (bcrlai,bweirr,snwc,bwtdmx,bwtdmn,
     *                      bmalat,bsfalw,bsfald,idoy,bwtdpt,bwzdpt)

c     + + + purpose + + +
c     this subroutine estimates the net radiation for a given area
c     using known solar radiation, air temperature, and vapor pressure
c     according to wright's (1982) modified version of penman's (1948)
c     relationship.

c     + + + key words + + +
c     radiation, hydrology, weps

c     + + + argument declarations + + +
      integer idoy
      real bcrlai
      real bweirr
      real snwc
      real bwtdmx
      real bwtdmn
      real bmalat
      real bsfalw
      real bsfald
      real bwtdpt
      real bwzdpt

c     + + + argument definitions + + +
c     bsfald   - dry albedo
c     bsfalw   - wet albedo
c     bmalat   - latitude of the site, degrees
c     idoy   - julian day of year, 1-366
c     bcrlai   - plant leaf area index
c     bwzdpt   - daily amount of percipitation, mm
c     bweirr     - solar radiation, mj/m^2
c     snwc   - water content of snow, mm
c     bwtdpt    - dew point temperature, c
c     bwtdmx   - maximum air temperature, c
c     bwtdmn   - minimum air temperature, c

c     + + + COMMON BLOCK + + +
*$noereference
      include 'p1const.inc'
*$reference

c     + + + local variables + + +
      real albt
      real tmink
      real tmaxk
      real rnb
      real tair
      real rlat
      real sigma
      real dr
      real ws
      real ra
      real ra1
      real ra2
      real rso
      real a
      real a1
      real b
      real e
      real rna
      real rno
      real sci

c     + + + local definitions + + +
c     albedo - overall albedo value
c     albs   - soil albedo

c     + + + parameters + + +

      real albp,coeff,gsc,sbc
c
      parameter   (albp = 0.23, coeff= -2.9e-5, gsc = 0.08202,
     &             sbc = 4.903e-9)

c     albp   - plant albedo
c     coeff  - coefficient in the equation to estimate soil cover index
c     gsc    - solar constant, mj/m^2-min
c     sbc    - stefan-boltzmann constant, mj/m^2/day

c     + + + data initialization + + +
c     + + + function calls + + +
      real albedo

c     + + + end specifications + + +


      albt = albedo (bcrlai, snwc, bsfalw,bsfald)

      tmaxk = bwtdmx + 273.15									!prereq h-17
      tmink = bwtdmn + 273.15									!prereq h-17
      tair = (bwtdmx + bwtdmn)/2								!prereq h-14
      rlat = bmalat*pi/180
      sigma = 0.4093*sin(2*pi*(284 + idoy)/365)					!h-23
      dr = 1 + 0.033*cos(2*pi*idoy/365)							!h-21
      ws = acos(-tan(rlat)*tan(sigma))							!h-22
      ra1 = ((24*60)/pi)*gsc*dr									!h-20(a)
      ra2 = (ws*sin(rlat)*sin(sigma))+(cos(rlat)*cos(sigma)		!h-20(b)
     &        *sin(ws))
      ra = ra1*ra2												!h-20
      rso = 0.75*ra												!h-19

      if ((bweirr/rso).gt.(0.7)) then
        a = 1.126
        b = -0.07
      else
        a = 1.017
        b = -0.06
      end if
      a1 = 0.26 + 0.1*exp(-((0.0154*(idoy - 180))**2))			!h-18
      e = exp((16.78*bwtdpt - 117)/(bwtdpt + 237.3))

      rna = (1-albt)*bweirr									!h-17(a)
      rno = (sbc*(tmaxk**4+tmink**4)/2)*(a1 - 0.139 * sqrt(e))	!h-17(b)
      rnb = (a*(bweirr/rso) + b)								!h-17(c)
      radnet = rna-(rno*rnb)									!h-17

      return
      end