!**********************************************************************
!      subroutine sbaglos
!**********************************************************************
      subroutine sbaglos (wus, wucsts,wucwts,wucdts,b1,b2,              &
     &  sf84ic,wust, svrocic, sf84mn, smaglos)
!
!     + + + PURPOSE + + +
!     calc. minimum erodible fraction (sf84mn) needed for threshold
!     friction velocity to equal current friction velocity on
!     aggregated surface
!
!     calc. potential mobile soil reservoir, smaglos, for a smooth
!     surface given friction velocity, flat biomass, wetness, and an
!     initial erodible fraction, sf84ic.
!
!     + + + ARGUMENT DECLARATIONS + + +
      real wus, wucsts,wucwts,wucdts,b1,b2
      real sf84ic, wust, svrocic
      real sf84mn, smaglos
!
!     + + +  ARGUMENT DEFINITIONS + + +
!     wus   - friction velocity (m/s)
!     wucsts- increase in threshold friction velocity from flat biomass (m/s)
!     wucwts- increase in threshold friction velocity from sfc wetness (m/s)
!     wucdts- decrease in threshold friction velocity from ag density (m/s)
!     b1,b2 - coef. calculated in threshold friction vel. eqn.
!     sf84ic- surface soil fraction <0.84 mm initial condition
!     svrocic - surface soil volume rock at start of event (m^3/m^3)
!     wust  - friction velocity theshold for en (m/s)
!     sf84mn- surface soil fraction <0.84 mm where wust= wus of ag.sfc.
!     smaglos- potential mobile soil reservoir of aggregated sfc.(kg/m^2)
!
!     + + + LOCAL VARIABLES + + +
      real wusto, scne
      real yinta, yintb, yint, yslpa, yslpb, yslp
!
!     + + + LOCAL VARIABLE DEFINITION + + +
!     wusto - threhold friction velocity = wus minus flat biomass and wetness
!             effects (m/s)
!     scne  - specifc clod cover (m^2/kg) of surface layer
!     yinta - part of ln y-intercept for smaglos
!     yintb - part of ln y-intercept for smaglos
!     yint  - ln y-intercept for smaglos
!     yslpa - part of ln y-slope for smaglos
!     yslpb - part of ln y-slope for smaglos
!     yslp  - ln y-slope for smaglos
!
!     + + + END SPECIFICATIONS + + +
!
!     calc.threshold=wus after accounting flat biomass and surface wetness
      wusto  = wus - wucsts - wucwts - wucdts
      if (wusto <1.7 ) then
        if (wusto > 0.221) then
!         calc loose agg. cover needed to give threshold=wusto
          sf84mn = 1 - (abs(alog((1.7-wusto)/1.35)+b1)/b2)**0.5
!         set lower limit
!         increase sf84mn among aggregates, if rock are present
          sf84mn = sf84mn/(1.0001-svrocic)
          sf84mn = amax1(0.0,sf84mn)
!
!        calc. reservoir of mobile soil, smaglos.
!          estimate of specific soil clod cover from SOIL ASD
          scne = 0.082 + 0.54*sf84ic*(1 - svrocic)
!
!        calc. Ln of y-intercpet for loose soil reservoir
          yinta = 3.67*scne**(-0.153)
          yintb = 1.095 + 0.2309*scne**0.5
          yint  = yinta + yintb*alog(wusto - 0.22)
!
!        calc. Ln of y-slope for loose soil reservoir
          yslpa = 0.07485 + 0.03748*scne**0.5
          yslpb = -0.014 + 0.1287*exp(-(wusto - 0.22)/0.0861)
          yslp  = yslpa + yslpb
!
!        calc. loose soil reservior for smooth soil with rock
          smaglos = exp(yint-yslp*((1-sf84ic)*(1-svrocic)+svrocic)*100)
        else
          smaglos = 0
          sf84mn  = 1
        endif
      else
!        leave variables at prior values- but should never occur!
         smaglos = smaglos
         sf84mn = sf84mn
      endif


!     smaglos is further reduced in sbqout by shelter area >12 deg.

      return
      end
!++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++