***********************************************************************
*      subroutine sbsfdi
***********************************************************************
      subroutine sbsfdi
     i (slagm, s0ags, slagn, slagx, sldi,
     o sfdi)
c
c     +++ PURPOSE +++
c     calc soil mass fraction (sfdi) < diameter (sldi)
c     given modified lognormal distribution parameters
c
c     +++ ARGUMENT DECLARATIONS +++
      real*4 slagm, s0ags, slagn, slagx, sldi, sfdi
c
c     +++  ARGUMENT DEFINITIONS +++
c     slagm - aggregate distribution geometric mean diameter (mm).
c     s0ags - aggregate distribution geometric standard deviation.
c     slagn - aggregate distribution lower limit (mm).
c     slagx - aggregate distribution upper limit (mm).
c     sldi  - soil diameter in distribution (mm)
c     sfdi  - soil mass fraction < sldi
c
c     +++ LOCAL VARIABLES +++
      real slt, erf
c
c     +++ FUNCTIONS CALLED+++
c     erf(x)
c
c     +++ END SPECIFICATIONS +++
c
c     calc soil mass < sldi
c
      if (sldi .lt. slagx .and. sldi .gt. slagn) then
        slt = ((sldi - slagn)*(slagx - slagn))/((slagx - sldi)*slagm)
        sfdi = 0.5*(1 + erf(alog(slt)/(sqrt(2.0)*alog(s0ags))))
      elseif (sldi .ge. slagx) then
        sfdi = 1.0
      else
        sfdi = 0.0
      endif
c
      return
      end
c++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++