subroutine kill( am0cgf,
     &     acxstm, tcxstm,
     &     acxstmrep, tcxstmrep,
     &     aczht, tczht,
     &     acdstm, tcdstm,
     &     acmst, tcmst,
     &     acmyld, tcmyld,
     &     acmrt, tcmrt,
     &     aczrtd, tczrtd,
     &     acmrtz, tcmrtz,
     &     nlay,
     &     acrlai)

c     + + + PURPOSE + + +
c
c     This subroutine performs the kill crop process and transferring of
c     biomass from crop to temporary pool.  Transfer of biomass is performed
c     on above ground biomass and the root biomass.  The transfer is
c     from the crop pool to the "temporary" crop pool.
c
c     + + + KEYWORDS + + +
c     kill, transfer, biomass manipulation

      include 'p1werm.inc'
c
c     + + + ARGUMENT DECLARATIONS + + +
c
      logical am0cgf
      real    acxstm, tcxstm
      real    acxstmrep, tcxstmrep
      real    aczht, tczht
      real    acdstm, tcdstm
      real    acmst, tcmst
      real    acmyld, tcmyld
      real    acmrt, tcmrt
      real    aczrtd, tczrtd
      real    acmrtz(mnsz), tcmrtz(mnsz)
      integer nlay
      real    acrlai

c
c     + + + ARGUMENT DEFINITIONS + + +
c
c     am0cgf      - flag to start and stop crop growth submodel
c     acxstm      - crop stem diameter
c     tcxstm      - temporary stem diameter
c     acxstmrep   - crop representative stem diameter
c     tcxstmrep   - temporary representative stem diameter
c     aczht       - crop height
c     tczht       - temporary crop height
c     acdstm      - number of stems
c     tcdstm      - temporary number of stems
c     acmst       - mass of standing biomass
c     tcmst       - temporary mass of standing biomass
c     acmyld      - mass of yield component
c     tcmyld      - temporary mass of yield component
c     acmrt       - mass of roots (total)
c     tcmrt       - temporary mass of roots (total)
c     aczrtd      - root depth
c     tczrtd      - temporary root depth
c     acmrtz(idx) - mass of roots (by layer)
c     tcmrtz(idx) - temporary mass of roots (by layer)
c     nlay        - number of soil layers
c     acrlai      - leaf area index
c
c     + + + ACCESSED COMMON BLOCK VARIABLE DEFINITIONS + + +
c
c     mnbpls        - max number of decomposition pools (currently=3)
c     mnsz          - max number of soil layers
c
c     + + + PARAMETERS + + +
c
c     + + + LOCAL VARIABLES + + +
c
      integer lay
c
c     + + + LOCAL VARIABLE DEFINITIONS + + +
c
c     lay        - soil layer index

c     + + + END SPECIFICATIONS + + +

c         need to stop the crop growth (ie. stop calling crop submodel)
          am0cgf = .false.

          !copy the stem diameter over
          tcxstm = acxstm
          !copy the representative stem diameter over
          tcxstmrep = acxstmrep
          !transfer plant properties to temporary pool
          tczht = max( tczht,aczht )  !crop height
          aczht = 0.0
          tcdstm = tcdstm + acdstm    !Number of stems
          acdstm = 0.0
          tcmst = tcmst + acmst       !mass of standing biomass
          acmst = 0.0
          tcmyld = tcmyld + acmyld    !mass of yield component
          acmyld = 0.0
          tcmrt = tcmrt + acmrt       !mass of roots (total)
          acmrt = 0.0
          tczrtd = max(tczrtd,aczrtd )!root depth
          aczrtd = 0.0
          do 666 lay=1,nlay           !mass of roots (by layer)
             tcmrtz(lay) = tcmrtz(lay) + acmrtz(lay)
             acmrtz(lay) = 0.0
666       continue

          ! once we move crop biomass into the "temporary" crop pool
          ! it is assumed to be dead biomass.  Currently we assume that
          ! dead biomass does not have "leaves" which significantly
          ! influence wind erosion.  Probably not a good generic assumption,
          ! but that's the way it is right now.
          acrlai = 0.0

      end