set term svg size 800,600 dynamic enhanced

set termoption dashed

set style line 1 lt 1 lc rgb "black" lw 1
set style line 2 lt 2 lc rgb "black" lw 1
set style line 3 lt 3 lc rgb "black" lw 1
set style line 4 lt 4 lc rgb "black" lw 1
set style line 5 lt 5 lc rgb "black" lw 1
set style line 6 lt 1 lc rgb "black" lw 2

ismin(x,y) = (x>y)?y:x
ismax(x,y) = (x>y)?x:y

set xlabel 'Random Roughness (mm)'
set ylabel 'Bare Soil Emission Ratio'

sarrc(slrr) = 2.3 * sqrt (slrr)
sargc(szrgh,sxprg) = 65.4*(szrgh/sxprg)**0.65
sfa12rr(slrr) = exp(-(12./sarrc(slrr))**0.77)
sfa12rg(szrgh,sxprg) = ((sxprg > 10.0) && (szrgh > 1.0))?exp(-(12./sargc(szrgh,sxprg))**0.77):0.
sfa12(slrr,szrgh,sxprg) =(1.- sfa12rg(szrgh,sxprg))*sfa12rr(slrr) + sfa12rg(szrgh,sxprg)

renb(sfcv,slrr,szrgh,sxprg) = (-0.051 + 1.051*exp(-sfcv/0.33050512))*(1 - sfa12(slrr,szrgh,sxprg))

#set log x
#set log y
set xrange [0:60]
set yrange [0:]
set key top right

# using decimal in numbers to ensure real division, not integer divistion
plot renb(0.,x,0.,0.) ls 1 with lines title 'SFcv = 0, no ridges' \
   , renb(0.,x,1.001,20.001) ls 2 with lines title 'SFcv = 0, 1/20 ridge height/spacing' \
   , renb(0.2,x,0.,0.) ls 3 with lines title 'SFcv = 0.2, no ridges' \
   , renb(0.5,x,0.,0.) ls 4 with lines title 'SFcv = 0.5, no ridges'
#pause -1