set term svg size 800,600 dynamic enhanced

set termoption dashed

set style line 1 lt 1 lc rgb "black" lw 1
set style line 2 lt 2 lc rgb "black" lw 1
set style line 3 lt 3 lc rgb "black" lw 1
set style line 4 lt 4 lc rgb "black" lw 1
set style line 5 lt 5 lc rgb "black" lw 1
set style line 6 lt 1 lc rgb "black" lw 2

ismin(x,y) = (x>y)?y:x
ismax(x,y) = (x>y)?x:y

set xlabel 'Mobile Mass on Crust (kg/m^2)'
set ylabel 'Fraction Loose Mobile Soil Crust Cover'

sz(szrgh,slrr) = ismax(szrgh, 4.0*slrr)
crlos(szrgh,slrr) = exp(-0.08*sqrt(sz(szrgh,slrr)))
sflos(smlos,szrgh,slrr) = (1.0 - exp(-3.5*smlos**1.5))*crlos(szrgh,slrr)

#set log x
#set log y
set xrange [0:1.5]
set yrange [0:1]
set key top left

# using decimal in numbers to ensure real division, not integer divistion
plot sflos(x,0.,1.5) ls 1 with lines title 'no ridge, 1.5mm random' \
   , sflos(x,10.,1.5) ls 2 with lines title '10mm ridge, 1.5mm random' \
   , sflos(x,40.,1.5) ls 3 with lines title '40mm ridge, 1.5mm random' \
   , sflos(x,100.,1.5) ls 4 with lines title '100mm ridge, 1.5mm random' \
   , sflos(x,0.,100.) ls 5 with lines title 'no ridge, 100mm random'

#pause -1