set term svg size 800,600 dynamic enhanced

set termoption dashed

set style line 1 lt 1 lc rgb "black" lw 1
set style line 2 lt 2 lc rgb "black" lw 1
set style line 3 lt 3 lc rgb "black" lw 1
set style line 4 lt 4 lc rgb "black" lw 1
set style line 5 lt 5 lc rgb "black" lw 1
set style line 6 lt 1 lc rgb "black" lw 2


ismin(x,y) = (x>y)?y:x
ismax(x,y) = (x>y)?x:y

set xlabel 'Wind-Ridge Angle'
set ylabel 'Aerodynamic Roughness (mm)'

set angles degrees
# calc. ridge spacing parallel the wind
sina(angle) = ismax(0.1,abs(sin(angle)))
sxprg(angle, asxrgs, asxdks) = (asxdks > asxrgs/3.)?ismin(asxrgs/sina(angle),asxdks):asxrgs/sina(angle)

# calc. for ridge aerodynamic roughness
hl(angle, asxrgs, asxdks, szrgh) = ismin(0.20,szrgh/sxprg(angle, asxrgs, asxdks))
wzorg(angle, asxrgs, asxdks, szrgh) = (szrgh>5)?szrgh * 1/(-64.1+135.5*hl(angle, asxrgs, asxdks, szrgh)+(20.84/sqrt(hl(angle, asxrgs, asxdks, szrgh)))):0

set xrange [0:90]
#set yrange [0:3100]
set key bottom

# using decimal in numbers to ensure real division, not integer divistion
plot wzorg(x,400.,100000.,100.) ls 1 with lines title '100mm height, 400mm spacing' \
   , wzorg(x,750.,100000.,200.) ls 2 with lines title '200mm height, 750mm spacing' \
   , wzorg(x,1000.,100000.,300.) ls 3 with lines title '300mm height, 1000mm spacing' \
   , wzorg(x,1000.,3000.,300.) ls 4 with lines title '300mm height, 1000mm spacing, 3000mm dikes'

#pause -1