set term svg size 800,600 dynamic enhanced

set termoption dashed

set style line 1 lt 1 lc rgb "black" lw 1
set style line 2 lt 2 lc rgb "black" lw 1
set style line 3 lt 3 lc rgb "black" lw 1
set style line 4 lt 4 lc rgb "black" lw 1
set style line 5 lt 5 lc rgb "black" lw 1
set style line 6 lt 1 lc rgb "black" lw 2

ismin(x,y) = (x>y)?y:x
ismax(x,y) = (x>y)?x:y

set xlabel 'Random Roughness (mm)'
set ylabel 'Sheltered Area Fraction'

sarrc(slrr) = 2.3 * sqrt (slrr)
sargc(szrgh,sxprg) = 65.4*(szrgh/sxprg)**0.65
sfa12rr(slrr) = exp(-(12./sarrc(slrr))**0.77)
sfa12rg(szrgh,sxprg) = ((sxprg > 10.0) && (szrgh > 1.0))?exp(-(12./sargc(szrgh,sxprg))**0.77):0.
sfa12(slrr,szrgh,sxprg) =(1.- sfa12rg(szrgh,sxprg))*sfa12rr(slrr) + sfa12rg(szrgh,sxprg)

#set log x
#set log y
set xrange [0:60]
set yrange [0:]
set key bottom right

# using decimal in numbers to ensure real division, not integer divistion
plot sfa12(x,0.,0.) ls 1 with lines title 'random roughness only' \
   , sfa12(x,1.001,100.001) ls 2 with lines title '1/100 ridge height/spacing' \
   , sfa12(x,1.001,20.001) ls 2 with lines title '1/20 ridge height/spacing' \
   , sfa12(x,2.001,10.001) ls 3 with lines title '1/5 ridge height/spacing'
#pause -1